* Encoding: UTF-8.
*Encoding: UTF-8.
**************** This syntax will reproduce all the analysis for the online e-cig misperceptions study (in SPSS [versions 24] only).
****************This syntax was created by  Madeleine Svenson on 05/06/2020

*creating a CRUK variable from the Qualtrics output*

RECODE Q6__CRUK_Page_Submit (1 thru 100000=1) INTO CRUK.
VARIABLE LABELS  CRUK 'CRUK'.
EXECUTE.

*creating an expert variable from Qualtrics output*

RECODE Q9_Expert_Page_Submit (1 thru 100000=3) INTO Expert.
VARIABLE LABELS  Expert 'Expert'.
EXECUTE.

*creating a Control variable from the Qualtrics output*

RECODE Q10 (1=4) INTO Control.
VARIABLE LABELS  Control 'Control'.
EXECUTE.

*CRUK, Expert and Control were combined into one variable called Condition*

RECODE CRUK Expert Control (1 thru 4 =COPY) (ELSE=0) INTO Expert_temp CRUK_temp Control_temp.
EXECUTE.

COMPUTE Condition=Expert_temp + CRUK_temp + Control_temp.
EXECUTE.

*value labelling for Condition*

VALUE LABELS Condition
1 "CRUK"
3 "Expert"
4 "Control".
EXECUTE.

*recoding system missing for Q27, how often do you currently use an e-cigarette of vaping device, as system missing users has previously answered that they do not use a vaping device*

RECODE Q27 (SYSMIS=7).

*********** exclusions
*excluding: unfinished surveys, Q15 2s 3s and 4s i.e non-daily smokers, Q11_6 particpants who failed the attention check and manipulation check (Q11 = condition)*

SELECT IF (Progress = 100) and (Q15 = 1) and  (Q11_6 = 1) and (Condition = Q11).
EXECUTE. 

SELECT IF (Q27 = 4) or (Q27 = 5) or (Q27 = 7).
EXECUTE.

***missing values***

MISSING VALUES Q11_1 to Q11_5 (8).
MISSING VALUES Q11_7 to Q13_7 (8).    
EXECUTE.

*Computing single variable from answers to FTND*

COMPUTE FTND=Q21 + Q22 + Q23 + Q24 + Q25 .
VARIABLE LABELS  FTND 'Fagerstom Test Nicotine Dependence'.
EXECUTE.

******to produce all the demographic table 1 data***

FREQUENCIES VARIABLES=Q15 Q16 Q17 Q18 Q19 Q20 Q21 Q22 Q23 Q24 Q25 Q26 Q27 Q28 Q29 Q30 Q31 Q32 Q33 
    Q34
  /STATISTICS=STDDEV MEAN
  /ORDER=VARIABLE.

FREQUENCIES VARIABLES=FTND
  /STATISTICS=STDDEV MEAN.
  EXECUTE.

*********************************analysis
***primary outcome analysis***
*For general and sepcific harm percpetions: one-way ANOVA, Brown-Forsythe, Games-Howell and Levenes*

ONEWAY Q11_1 Q11_2 Q11_3 Q11_4 Q11_5 Q11_7 Q13_1 Q13_2 Q13_3 Q13_4 Q13_5 Q13_6 Q13_7 BY Condition
  /STATISTICS DESCRIPTIVES HOMOGENEITY BROWNFORSYTHE WELCH 
  /MISSING ANALYSIS
  /POSTHOC=GH ALPHA(0.05).
EXECUTE.

*partial eta squared and standard error*

MEANS TABLES=Q11_1 Q11_2 Q11_3 Q11_4 Q11_5 Q11_7 Q13_1 Q13_2 Q13_3 Q13_4 Q13_5 Q13_6 Q13_7 BY Condition
/CELLS=MEAN COUNT SEMEAN
/STATISTICS ANOVA.
EXECUTE.

* Biggest concern frequencies and percentage for Table 2*

FREQUENCIES VARIABLES=Q14
  /BARCHART PERCENT
  /ORDER=ANALYSIS.
EXECUTE.

SORT CASES  BY Condition.
SPLIT FILE SEPARATE BY Condition.

FREQUENCIES VARIABLES=Q14
  /BARCHART PERCENT
  /ORDER=ANALYSIS.
EXECUTE.

SPLIT FILE OFF.
EXECUTE.

*Chi squared and phi and cramers V for intention to tru e-cigaerttes in the future of use them in a future quit attempt*

CROSSTABS
  /TABLES=Q57_1 Q57_2 BY Condition
  /FORMAT=AVALUE TABLES
  /STATISTICS=CHISQ PHI 
  /CELLS=COUNT ROW COLUMN TOTAL 
  /COUNT ROUND CELL.
EXECUTE.